Tips Visual Basic - Cara Menjalankan Program Lain Dengan Berbagai Model Jendela

Pada tips visual basic kali ini, kita akan mempraktekkan cara menjalankan program lain (seperti Notepad, Paint, dan lainnya) dengan berbagai macam model jendelanya, seperti maximized, minimized, normal, atau bahkan menyembunyikan jendelanya alias program tersebut akan berjalan di belakang layar. Juga bisa ditentukan apakah jendela program itu akan fokus atau tidak fokus.

Kita akan membuat contoh programnya dulu, di sini saya membuat sebuah project StandardExe di Visual Basic. Kontrol-kontrolnya terdiri dari: CommandButton (cmdJalankanProgram), Textbox (txtProgram), dan ComboBox (cboModelJendela). Tampilannya seperti gambar di atas. Lalu untuk kode-kodenya adalah sebagai berikut:

Option Explicit

Private Enum enumJenisJendela
    Normal_dan_Fokus = vbNormalFocus
    Normal_Tidak_Fokus = vbNormalNoFocus
    Maximized = vbMaximizedFocus
    Minimized_dan_Fokus = vbMinimizedFocus
    Minimized_Tidak_Fokus = vbMinimizedNoFocus
    SembunyikanJendela = vbHide
End Enum

Private Sub JalankanProgram(sProgramPath As String, JenisJendela As enumJenisJendela)
    On Error GoTo Er:
    'cek jika file program tersebut tidak ada
    If Dir(sProgramPath) = "" Then
        MsgBox "File Tidak Ditemukan: " & sProgramPath
        Exit Sub
    End If
    'jalankan program
    Shell sProgramPath, JenisJendela
    Exit Sub
Er:
    MsgBox "Error menjalankan program " & sProgramPath & vbCrLf & _
        "Penjelasan: " & Err.Description, , "Error"
End Sub

Private Sub cmdJalankanProgram_Click()
    If cboModelJendela.ListIndex = 0 Then JalankanProgram txtProgram.Text, Normal_dan_Fokus
    If cboModelJendela.ListIndex = 1 Then JalankanProgram txtProgram.Text, Normal_Tidak_Fokus
    If cboModelJendela.ListIndex = 2 Then JalankanProgram txtProgram.Text, Maximized
    If cboModelJendela.ListIndex = 3 Then JalankanProgram txtProgram.Text, Minimized_dan_Fokus
    If cboModelJendela.ListIndex = 4 Then JalankanProgram txtProgram.Text, Minimized_Tidak_Fokus
    If cboModelJendela.ListIndex = 5 Then JalankanProgram txtProgram.Text, SembunyikanJendela
End Sub

Private Sub Form_Load()
    cboModelJendela.AddItem "Normal dan Fokus"
    cboModelJendela.AddItem "Normal, Tidak Fokus"
    cboModelJendela.AddItem "Maximized"
    cboModelJendela.AddItem "Minimized dan Fokus"
    cboModelJendela.AddItem "Minimized, Tidak Fokus"
    cboModelJendela.AddItem "Sembunyikan Jendela"
    cboModelJendela.ListIndex = 0
End Sub

Keterangan: 
Fungsi utamanya adalah pada teks berwarna biru. 
Warna merah adalah listing kode untuk tombol cmdJalankanProgram (CommandButton). 
Warna merah muda adalah kode untuk Form. 

Saat dijalankan, isikan nama file program lengkap bersama pathnya, lalu pilih jenis jendelanya, kemudian klik tombol Jalankan. 

Keterangan Untuk Model Jendela:
- Fokus / Tidak fokus : menunjukkan apakah jendela program akan aktif (berada di depan jendela program lain) atau tidak.
- Normal : Tampilan standar jendela
- Maximized : Jendela akan menutupi seluruh desktop kecuali Taskbar.
- Minimized : Jendela program tidak terlihat tetapi tombol program masih ada di Taskbar. Dengan meng-klik tombol program di taskbar maka jendelanya akan muncul kembali.
- Sembunyikan jendela : Jendela program tidak terlihat begitu pula tombolnya di taskbar. Untuk menutup programnya, anda harus membuka Task Manager, caranya tekan CTRL+ALT+DEL. Lalu pada jendela Task Manager, klik tab Processes, lalu cari dan pilih program yang dijalankan, kemudian klik tombol End Process. Tampilan Task Manager seperti berikut ini:

Artikel ini ditulis oleh Gilang ramadhan.
<a href="http://justfor-gamers.blogspot.com/2013/12/tips-visual-basic-cara-menjalankan.html">Tips Visual Basic - Cara Menjalankan Program Lain Dengan Berbagai Model Jendela</a>

Sobat sedang membaca artikel tentang Tips Visual Basic - Cara Menjalankan Program Lain Dengan Berbagai Model Jendela dan sobat bisa menemukan artikel Tips Visual Basic - Cara Menjalankan Program Lain Dengan Berbagai Model Jendela ini dengan url http://justfor-gamers.blogspot.com/2013/12/tips-visual-basic-cara-menjalankan.html, sobat boleh menyebar luaskannya atau mengcopy paste-nya jika artikel Tips Visual Basic - Cara Menjalankan Program Lain Dengan Berbagai Model Jendela ini sangat bermanfaat bagi teman-teman sobat, namun jangan lupa untuk meletakkan link Tips Visual Basic - Cara Menjalankan Program Lain Dengan Berbagai Model Jendela sumbernya. Terima kasih.